**备注提示：内文体例与格式**

**章 第一章 1** 每一章之间有两行空距

……

代码块通常须缩进展示，并在上下方与正文的其他部分有一行的空距

**基于中华传统音乐馆藏资源的“知识库”建设**

**和“知识地图”研究**

（2.0 目录及重点批注）

**1 中华传统音乐文化知识库一期及相关研究回溯**

（1）现存的问题：语义网站点未真正打通、后端知识推理尚未激活、可视化使用平台效果不足、未开通图书馆员维护平台，等等

（2）重点回顾二期迭代方案

（3）对一期技术选型优势的介绍：即灵活性和可拓展性；知识图谱所代表的符号主义AI+大语言模型所代表的连接主义AI；产品性优势的介绍，比如，曲目的演出的细颗粒度、元数据+数据——双层架构的产品定位

（4）LinkedMusic研究方案的启发（这个方案主要就是在线音乐数据库资源共建技术方案）

（5）根本问题意识：有了大模型，我们为什么仍要迂回地做知识图谱？

**2 中华传统音乐文化知识库二期开发成果述介与分析**

已解决前述“现存的问题”

**2.1 增补数据与检索分析**

2.1.1 基于大模型的（乐器）知识图谱自动化智能知识抽取研究

2.1.2 增补数据与检索示例

首先，提出“语义网”作为数据库，在检索方面的重要优势，在图书馆业务环境下的关联数据发布等。然后：

1. 新版本体(2.0)的简介（看看能否植入SHACL及对VOID的数据分析）

（2）东方乐器数据（+图片）的植入、局内人视角的检索案例

（3）关联Wikidata（维基百科对应的知识图谱）的示例（乐种、乐器）与跨数据库检索示例

（4）关联中国音乐学院实体乐器博物馆乐器编目

（5）乐器分类法（霍萨分类法+“概念->单件”垂直分类体系）

（6）激活推理机的数据增补（含owl:sameAs所链接的语义网站点）

推理机：……探索其他高级推理的效用，如2.3.1.1用到对称关系

（7）新增中华传统音乐馆藏资源链接等

**2.2 可视化与后端平台功能介绍与案例分析**

2.2.1 前端可视化网络分析功能（2.0版）

如路径查询等

2.2.2 后端（如图书馆员维护平台）

增、删、改、查、术语维护、关联数据发布平台

**2.3 “知识地图”案例拓展**

增补地理信息数据，可用以检索我国任意一级行政单位（村、寨除外）的乐种、乐器等信息

2.3.1 检索案例分析

2.3.1.1 地域毗邻关系检索：检索相邻地域的乐种分布

2.3.1.2 地理坐标距离检索：精确检索乐种间的地理距离、特定地域范围的乐种、资源等

2.3.2 知识地图研究意义小结

基于规则的数据补齐[[1]](#footnote-0)：目前只做了一部分……实现了，可以自动化地查询中国任意地域的乐种、乐器等分布信息，并比照中华传统音乐资源库的收录情况，回答这样的问题：某地有什么样的乐种、乐器，在我馆是否有收藏……

**3 基于大语言模型的知识库智能检索系统（后端）开发**

**3.1 研究的问题、意义与背景综述**

知识库建设最终的目的是服务于信息检索。然而，一方面，网站中所涉的检索技术始终无法脱离页面设计的局限性；另一方面，前论述中绝大多数的信息检索都依赖于专业的检索语言SPARQL——这会让一般的音乐用户望而却步。而本章要解决的问题有二：

1. 将用户提出自然语言问题通过大语言模型自动转化为SPARQL，获取检索结果并做自动阐释：这样，用户就不一定得会用SPARQL才能做语义检索
2. 此外，启发（音乐数字人文研究者）掌握基于SPARQL的结构化检索语言，乃至熟悉音乐知识组织技术

**3.2 本体驱动的NLQ2SPARQL技术流分析**

3.2.1 本体编辑与激活基于本体的知识推理

3.2.2 本体切片

3.2.3 基于本体的实体（类和属性）提取

3.2.4 子图拼装

3.2.5 基于子图的NLQ2SPARQL

（NLQ即natural language question。即将自然语言问题转化成查询语句）

3.2.6 检索增强生成与基于本体的音乐推荐

例如，将本体本身看成一个知识地图，然后进行音乐推荐

**3.3 具体检索案例分析：中华传统音乐馆藏资源+知识库**

**4 总结与展望**

研究的不足与改进方向、未来规划：

1. 已有数据存在的问题：乐器数据有待优化，比如，存在中文IRI的情况；关于对原文本中，“或”关系或“且”关系的抽取存在问题

（1）优化NLQ2SPARQL工作流，强化检索增强生成的功能

（2）智能体开发：强化交互、启发用户与推荐系统

（3）细粒度检索：乐谱+音频

（4）多模态知识图谱\*

（5）本体映射与多数据库开放、关联、共享、共建（基于VOID生成Ontology的思想的联邦查询，LinkedMusic案例）

结语：大模型+知识库+提示词工程+RAG

**基于中华传统音乐馆藏资源的“知识库”建设**

**和“知识地图”研究**

（2.0 正文）

中华传统音乐文化知识库（以下简称知识库）

**2.3 “音乐地图”案例拓展**

增补地理信息数据，可用以检索我国任意一级行政单位（村、寨除外）的乐种、乐器等信息

**2.3.1 检索案例分析**

2.3.1.1 地域毗邻关系检索

在2.0版的知识库中，补充了各市级行政单位的毗邻关系数据，借助这种毗邻关系的结构，也可比较有效地以知识网络可视化的方式，对应地理区位分布关系展示特定范围的乐种信息，譬如，问：

与河北省石家庄市相邻3步长范围内的其他城市及其下属各级行政单位会有什么乐种？就这些乐种，我馆是否收藏了一些特藏资源？

如下的检索方案先回答前半部分的问题“与河北省石家庄市相邻3步长范围内的其他城市及其下属各级行政单位会有什么乐种？”

define input:inference 'urn:owl.ccmusicrules0214'

PREFIX ctm: <https://lib.ccmusic.edu.cn/ontologies/chinese\_traditional\_music#>

PREFIX places: <http://purl.org/ontology/places#>

PREFIX gn: <https://www.geonames.org/ontology#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX bf: <http://id.loc.gov/ontologies/bibframe/>

SELECT DISTINCT ?MusicType ?MusicTypeName ?adminUnit ?adminUnitName ?SpecialIndependentResource ?SIR\_Label

WHERE {

# Identify Shijiazhuang city

?shijiazhuang rdfs:label "石家庄市" .

?shijiazhuang a places:City .

# Find cities within 3 steps of Shijiazhuang

{

# Include Shijiazhuang itself

BIND(?shijiazhuang AS ?city)

} UNION {

# Direct neighbor (1 step)

?shijiazhuang gn:neighbour ?city .

} UNION {

# 2 steps away

?shijiazhuang gn:neighbour ?intermediateCity1 .

?intermediateCity1 gn:neighbour ?city .

FILTER(?city != ?shijiazhuang)

} UNION {

# 3 steps away

?shijiazhuang gn:neighbour ?intermediateCity1 .

?intermediateCity1 gn:neighbour ?intermediateCity2 .

?intermediateCity2 gn:neighbour ?city .

FILTER(?city != ?shijiazhuang && ?city != ?intermediateCity1)

}

# Find administrative units at all levels under these cities

{

# The city itself

BIND(?city AS ?adminUnit)

} UNION {

# Counties under the city

?county gn:parentADM2 ?city .

BIND(?county AS ?adminUnit)

} UNION {

# Towns under counties

?county gn:parentADM2 ?city .

?town gn:parentADM3 ?county .

BIND(?town AS ?adminUnit)

} UNION {

# Villages under towns

?county gn:parentADM2 ?city .

?town gn:parentADM3 ?county .

?village gn:parentADM4 ?town .

BIND(?village AS ?adminUnit)

}

# Find music types associated with these administrative units

?MusicType bf:place ?adminUnit .

# Get names for readability

?adminUnit rdfs:label ?adminUnitName .

?MusicType rdfs:label ?MusicTypeName .

# Filter out any results where ?MusicTypeName contains pinyin (values with @py language tag)


FILTER(LANG(?MusicTypeName) != "py")

# 就这些乐种，我馆是否收藏了一些特藏资源？如果有，请将其返回

optional { ?SpecialIndependentResource ctm:relatesMusicType ?MusicType ; rdfs:label ?SIR\_Label }

}

根据如上代码，返回的结果如：



图

如榆社县（属于晋中市）的左权小花戏，对应的我馆特藏资源名称为《采访山西左权县“小花戏”李时珍等》。其他（截图之外的）有祁县（属于晋中市）的祁太秧歌，对应的我馆特藏资源名称为《王西麟音乐会（中山音乐堂）》；有涞水县（属于保定市）的“河北音乐会-北乐会”，对应的我馆特藏资源名称为《河北省屈家营音乐会重建二十四周年（演奏篇）：屈家营“音乐圣会”世界音乐周专场音乐会》。另外，须注意，返回的第1-91, 178-235, 389, 408-412, 420-441条数据，相应的乐种则在我馆特藏独立资源中有收藏，且对应的行政单位为县区级；其他的对应的行政单位基本为乡镇级或村寨级的；等等。

2.3.1.1.1 地域毗邻关系检索的知识网络可视化操作示例

首先，可以展示石家庄市及与其相邻的2步长范围内的其他城市（参考如下SPARQL代码Part 1）及这些城市所有的下辖县区级行政单位（代码Part 2）构成的邻接关系网络[[2]](#footnote-1)；其二，在此基础上关联与县级行政单位相邻的乐种（代码Part 3）；其三，再关联与关联到的乐种相关联的特藏独立资源（代码Part 4）。

可以通过SPARQL语句，逐步获取数据：

define input:inference 'urn:owl.ccmusicrules0214' # 用于Open Link Virtuoso中激活推理机

PREFIX bf: <http://id.loc.gov/ontologies/bibframe/>

PREFIX ctm: <https://lib.ccmusic.edu.cn/ontologies/chinese\_traditional\_music#>

PREFIX gn: <https://www.geonames.org/ontology#>

PREFIX places: <http://purl.org/ontology/places#>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

# 注意：激活变量?distance，则可显示相应的边列表关系是第几步长范围内的

SELECT distinct ?source ?sourceLabel ?target ?targetLabel ?relationType #?distance

WHERE {

# Identify 石家庄市 as our starting point

?shijiazhuang rdfs:label "石家庄市" .

?shijiazhuang a places:City .

{

**# Part 1: City-to-City connections 城市间的毗邻关系**

{

# Direct neighbors (1 step)

?shijiazhuang gn:neighbour ?target .

BIND(?shijiazhuang AS ?source)

BIND(1 AS ?distance)

BIND(gn:neighbour AS ?relationType)

}

UNION

{

# 2 steps away

?shijiazhuang gn:neighbour ?intermediate1 .

?intermediate1 gn:neighbour ?target .

FILTER(?target != ?shijiazhuang) # Avoid cycles back to origin

BIND(?intermediate1 AS ?source)

BIND(2 AS ?distance)

BIND(gn:neighbour AS ?relationType)

}

# Get readable labels for cities

?source rdfs:label ?sourceLabel .

?target rdfs:label ?targetLabel .

}

UNION

**{**

**# Part 2: County-to-City relationships 县、区级行政单位到市级行政单位的信息**

{

# Direct parent-child relationship - counties of Shijiazhuang

?county gn:parentADM2 ?shijiazhuang .

?county a places:County .

?county rdfs:label ?sourceLabel .

?shijiazhuang rdfs:label ?targetLabel .

BIND(?county AS ?source)

BIND(?shijiazhuang AS ?target)

BIND(gn:parentADM2 AS ?relationType)

}

UNION

{

# Counties of neighboring cities

?shijiazhuang gn:neighbour ?neighborCity .

?neighborCity a places:City .

?county gn:parentADM2 ?neighborCity .

?county a places:County .

?county rdfs:label ?sourceLabel .

?neighborCity rdfs:label ?targetLabel .

BIND(?county AS ?source)

BIND(?neighborCity AS ?target)

BIND(gn:parentADM2 AS ?relationType)

}

UNION

{

# Counties of cities 2 steps away

?shijiazhuang gn:neighbour ?intermediate1 .

?intermediate1 gn:neighbour ?distantCity .

FILTER(?distantCity != ?shijiazhuang)

?distantCity a places:City .

?county gn:parentADM2 ?distantCity .

?county a places:County .

?county rdfs:label ?sourceLabel .

?distantCity rdfs:label ?targetLabel .

BIND(?county AS ?source)

BIND(?distantCity AS ?target)

BIND(gn:parentADM2 AS ?relationType)

}

**}**

UNION

{

**# Part 3: MusicType-to-County relationships 乐种及其分布地域（仅以县区级行政单位为例）**

{

# Music types related to counties in Shijiazhuang

?county gn:parentADM2 ?shijiazhuang .

?county a places:County .

?musicType bf:place ?county .

?musicType rdfs:label ?sourceLabel .

?county rdfs:label ?targetLabel .

BIND(?musicType AS ?source)

BIND(?county AS ?target)

BIND(bf:place AS ?relationType)

FILTER(LANG(?sourceLabel) != "py")

}

UNION

{

# Music types related to counties in neighboring cities

?shijiazhuang gn:neighbour ?neighborCity .

?neighborCity a places:City .

?county gn:parentADM2 ?neighborCity .

?county a places:County .

?musicType bf:place ?county .

?musicType rdfs:label ?sourceLabel .

?county rdfs:label ?targetLabel .

BIND(?musicType AS ?source)

BIND(?county AS ?target)

BIND(bf:place AS ?relationType)

FILTER(LANG(?sourceLabel) != "py")

}

UNION

{

# Music types related to counties in cities 2 steps away

?shijiazhuang gn:neighbour ?intermediate1 .

?intermediate1 gn:neighbour ?distantCity .

FILTER(?distantCity != ?shijiazhuang)

?distantCity a places:City .

?county gn:parentADM2 ?distantCity .

?county a places:County .

?musicType bf:place ?county .

?musicType rdfs:label ?sourceLabel .

?county rdfs:label ?targetLabel .

BIND(?musicType AS ?source)

BIND(?county AS ?target)

BIND(bf:place AS ?relationType)

FILTER(LANG(?sourceLabel) != "py")

}

}

UNION

{

**# Part 4: SpecialIndependentResource-to-MusicType relationships 特藏独立资源及其涉及的乐种**

{

# specialResources related to musicTypes in Shijiazhuang counties

?county gn:parentADM2 ?shijiazhuang .

?county a places:County .

?musicType bf:place ?county .

?specialResource a ctm:SpecialIndependentResource .

?specialResource ctm:relatesMusicType ?musicType .

?specialResource rdfs:label ?sourceLabel .

?musicType rdfs:label ?targetLabel .

BIND(?specialResource AS ?source)

BIND(?musicType AS ?target)

BIND(ctm:relatesMusicType AS ?relationType)

FILTER(LANG(?targetLabel) != "py")

}

UNION

{

# specialResources related to musicTypes in neighboring cities' counties

?shijiazhuang gn:neighbour ?neighborCity .

?neighborCity a places:City .

?county gn:parentADM2 ?neighborCity .

?county a places:County .

?musicType bf:place ?county .

?specialResource a ctm:SpecialIndependentResource .

?specialResource ctm:relatesMusicType ?musicType .

?specialResource rdfs:label ?sourceLabel .

?musicType rdfs:label ?targetLabel .

BIND(?specialResource AS ?source)

BIND(?musicType AS ?target)

BIND(ctm:relatesMusicType AS ?relationType)

FILTER(LANG(?targetLabel) != "py")

}

UNION

{

# specialResources related to musicTypes in counties of cities 2 steps away

?shijiazhuang gn:neighbour ?intermediate1 .

?intermediate1 gn:neighbour ?distantCity .

FILTER(?distantCity != ?shijiazhuang)

?distantCity a places:City .

?county gn:parentADM2 ?distantCity .

?county a places:County .

?musicType bf:place ?county .

?specialResource a ctm:SpecialIndependentResource .

?specialResource ctm:relatesMusicType ?musicType .

?specialResource rdfs:label ?sourceLabel .

?musicType rdfs:label ?targetLabel .

BIND(?specialResource AS ?source)

BIND(?musicType AS ?target)

BIND(ctm:relatesMusicType AS ?relationType)


FILTER(LANG(?targetLabel) != "py")

}

}

}

根据如上，它返回的结果是一个“类型化边列表格式”的数据，即从源节点（source）指向目标节点（target）的列表：




……

图

如上图所示（“Show 1000 entries”，共返回672行结果），而就所谓类型化边列表格式，可见其最右列对连边的类型做出了标注。在此返回的数据中，依次共有4种类型：<https://www.geonames.org/ontology#neighbour>(市级行政单位与另一市级行政单位毗邻), gn:parentADM2(县、区级行政单位地域隶属于), <

<http://id.loc.gov/ontologies/bibframe/place>(分布地域),> ctm:relatesMusicType。点击上图红圈所示的下载按钮，可以获得CSV格式的数据，并进行异构知识网络分析。

仅须简单的数据处理，然后，为了视图的简化，比如，筛除那些没有关联任何乐种的县、区级行政单位，作图及显示如下[[3]](#footnote-2)：









图 城市、县区、乐种、特藏资源间的异构知识网络（2024Apr20）

该图采用了弹簧模型布局，适当放大了高节点中心度的节点。图例中有关于“数字标识符—节点标签”的列表：图中部分节点的标签过长，加上展示空间有限，故对节点标签采用数字标识符替代，从而读者可在列表中查找相应标识符所匹配的标签

……我们还可以通过筛除掉“没有关联特藏资源的乐种所分布的区县”而更清楚地观察：中国音乐学院图书馆特藏资源—乐种—县—以石家庄市为中心2步长范围内的市[[4]](#footnote-3)——它们之间的语义关系：






图 城市、县区、乐种、特藏资源间的异构知识网络（有删节）

2.3.1.2地理坐标距离检索

地域毗邻关系检索毕竟只是以网络拓扑结构的方式展示近似地图分布的数据信息。有时，根据毗邻关系捕获的数据是意料之外的，却缺乏了真实空间定位的参考性。譬如，返回与湖北省相邻2步长的其他省份，会发现，中国所有的省都包括在内了……要想更精确地呈现音乐地图，最好是通过地理坐标距离进行检索。

在2.0版的知识库中，补充了湖北省所有县级行政单位的地理坐标信息，例如，武汉市武昌区的坐标为东经114.316520度，北纬30.553860度。以RDF数据表示，诸如湖北省的武昌区、随县、赤壁市（县级市）的坐标信息记录如下：

@prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#> .

@prefix wdt: <http://www.wikidata.org/prop/direct/> .

@prefix geo: <http://www.openlinksw.com/schemas/virtrdf#> .

<https://lib.ccmusic.edu.cn/data/place/420106> rdfs:label "武昌区" ;

wdt:P625 "POINT(114.31652 30.55386)"^^geo:Geometry .

<https://lib.ccmusic.edu.cn/data/place/421321> rdfs:label "随县" ;

wdt:P625 "POINT(113.29995 31.8538)"^^geo:Geometry .

……[[5]](#footnote-4)

湖北省荆门市（东宝区）方圆75公里内有哪些乐种，其中，哪些在我们图书馆有收藏？

define input:inference 'urn:owl.ccmusicrules0214' # 用于激活Virtuoso中的推理机

PREFIX gn: <https://www.geonames.org/ontology#>

PREFIX ctm: <https://lib.ccmusic.edu.cn/ontologies/chinese\_traditional\_music#>

PREFIX bf: <http://id.loc.gov/ontologies/bibframe/>

PREFIX wdt: <http://www.wikidata.org/prop/direct/>

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

select distinct ?OtherCity ?OtherCounty ?distance ?MusicType2 ?MusicType3 ?SpecialIndependentResource

where {

# （1）找到荆门市中心的东宝区的坐标，以及东宝区可能存在的音乐类型(乐种)：

?CenterCounty rdfs:label "东宝区" ;

wdt:P625 ?centerCoordinateLocation .

optional { ?MusicType1 bf:place ?CenterCounty ; a ctm:MusicType } # [随后事实发现，并没有音乐类型(乐种)是直接关联东宝区的]

# （2）规定好备选的其他县区级行政单位的坐标，以及其所隶属的市级行政单位，以及隶属于该县区级行政单位的乡镇级行政单位：

?OtherCounty wdt:P625 ?otherCoordinateLocation ; # P625为坐标属性

gn:parentADM2 ?OtherCity . # 县、区级行政单位地域隶属于某市级行政单位?OtherCity

?OtherTown gn:parentADM3 ?OtherCounty . # 某些乡镇级行政单位?OtherTown隶属于该县级行政单位（假定一个县区级行政单位必然有下辖的乡镇级行政单位）

# （3）如果某些音乐类型(乐种)的分布地域是那些县区级或市级行政单位，进而，如果这些音乐类型涉及到我馆的特藏独立资源

{

optional { ?MusicType2 a ctm:MusicType ;

bf:place **?OtherCounty** .

optional { ?MusicType2 ctm:relatesWork ?SpecialIndependentResource . }

}

optional { ?MusicType3 a ctm:MusicType ;

bf:place **?OtherCity** .

optional { ?MusicType3 ctm:relatesWork ?SpecialIndependentResource . }

}

optional { ?MusicType4 a ctm:MusicType ;

bf:place **?OtherTown** .

optional { ?MusicType4

ctm:relatesWork ?SpecialIndependentResource . }

}

}

#（4）计算东宝区和其他县级行政单位之间的距离，设筛选条件为60公里之内

bind (bif:st\_distance(?centerCoordinateLocation, ?otherCoordinateLocation) AS ?distance)

filter (?distance<=75)

} order by ?distance

为了解答如上问题，基本思路是：荆门市的中心为东宝区，所以以该区的坐标代表该市的中心坐标……所用到的属性http://www.wikidata.org/prop/direct/P625即coordinate location（坐标位置）。

注意，就这个问题，它用到了特殊的SPARQL 函数

检索检索：136行数据（（在滤除修订、增补的内容的前提下)）——如果不返回乐种名，它会包含拼音名，造成统计上的重复）。例如，荆门市的府河傢业、天沔小曲，其下辖的县级市，又有梁山调，等等。

**2.3.2 知识地图研究意义小结**

在这里可以补上对“城市、县区、乐种、特藏资源间的异构知识网络（2024Apr20）”一图对应的原始数据的基于提示词工程的数据分析，正好用于承上启下

**3 基于大语言模型的知识库智能检索系统（后端）开发**

**3.1 研究的问题、意义与背景综述**

对于2.3.1（1）的问题“与河北省石家庄市相邻4步长范围内的其他城市及其下属各级行政单位会有什么乐种？……”：

提示词/prompt:

Given

```

@prefix ctm: <https://lib.ccmusic.edu.cn/ontologies/chinese\_traditional\_music#> .

@prefix places: <http://purl.org/ontology/places#> .

@prefix gn: <https://www.geonames.org/ontology#> .

# 类：

ctm:MusicType rdfs:label "乐种" .

ctm:SpecialIndependentResource rdfs:label "特藏资源" .

ctm:Town rdfs:subClassOf bf:Place .

places:City rdfs:subClassOf bf:Place .

places:County rdfs:subClassOf bf:Place .

places:Village rdfs:subClassOf bf:Place .

# 属性：

bf:place rdfs:label "分布地域" .

rdfs:range bf:Place .

ctm:relatesMusicType rdfs:domain [ owl:intersectionOf ( ctm:SpecialIndependentResource [ rdf:type owl:Class ; owl:complementOf ctm:PieceWithPerformance ]) ;

rdf:type owl:Class ] ;

rdfs:range ctm:MusicType ;

rdfs:label "特藏资源涉及…音乐类型(乐种)" .

gn:neighbour rdfs:label "市级行政单位与另一市级行政单位毗邻" ;

rdfs:domain places:City ;

rdfs:range places:City .

gn:parentADM2 rdf:type owl:ObjectProperty ;

rdfs:domain places:County ;

rdfs:range places:City ;

rdfs:label "县、区级行政单位地域隶属于" .

gn:parentADM3 rdf:type owl:ObjectProperty ;

rdfs:domain ctm:Town ;

rdfs:range places:County ;

rdfs:label "乡、镇级行政单位地域隶属于" .

gn:parentADM4 rdf:type owl:ObjectProperty ;

rdfs:domain places:Village ;

rdfs:range ctm:Town ;

rdfs:label "村、社区级行政单位地域隶属于" .

```

, for the question “与河北省石家庄市（rdfs:label “石家庄市”）相邻3步长范围内的其他城市及其下属各级行政单位会有什么乐种？”, please create a corresponding SPARQL

对于2.3.1.1.1的异构网络绘制，提示词可参考文档promptFor2.3.1.1.1.md。

1. 比如，一个乐种分布在某（乡镇）级行政单位，那么可理解，该乐种也应该分布在该（乡镇）级行政单位所有的上级行政单位，通过基于规则的推理，目前已补齐这方面的数据（我记不清对于乐器，是否也已补齐此数据了，待查）。同样的，未来可考虑其他能补齐的数据：如果一个特藏资源涉及某级行政单位…… [↑](#footnote-ref-0)
2. 与上例相比，该例略做了简化改动，即将原来的3步长范围改为了2步长范围，同时，将原来的“下属各级行政单位”改成了“下辖县区级行政单位” [↑](#footnote-ref-1)
3. 参考python作图代码2.3.1.1.1.py [↑](#footnote-ref-2)
4. 参考python作图代码2.3.1.1.1forSpecialIndependentResource，下图在显示中，有节略，可另参考 [↑](#footnote-ref-3)
5. 这些数据直接来自对chatGpt的询问。一般而言，行政单位不宜过大，否则面积太大，则不宜以单坐标点表示其位置；也不宜过小，否则区分度不够，大语言模型也未必能给出完备、准确的坐标数据 [↑](#footnote-ref-4)